Math Help -> Counting and Combinations -> Countable -> Counting ordered pairs of integers 

I will give you a formula for finding x_n and y_n for any positive integer n, so that the point (x_n,y_n) is the n^th element of the sequence you're describing.  There's also a calculator you can use to quickly find the nth ordered pair.

I will use intermediate variables in the calculation to make the explanation clear.

The variables I will use are:

Shell -- the number of the square, in other words its distance from the origin.

Leg -- a number 0, 1, 2, or 3 indicating which leg of the square the n^th point belongs to.

Element -- a number from -Shell+1 to Shell giving the position of the n^th point on the given leg of the given shell.

Now for the calculation...

Shell = integer((sqrt(n)+1)/2)

Leg = integer((n-(2*Shell-1)^2)/(2*Shell))

Element = (n-(2*Shell-1)^2)-2*Shell*Leg-Shell+1

x_n = Leg==0? Shell: Leg==1? -Element: Leg==2? -Shell: Element

y_n = Leg==0? Element : Leg==1? Shell : Leg==2? -Element : - Shell

In the first row, put your column labels: n, Shell, Leg, Element, x, y.

In the second row, put your formulas.

The cell in column A has no formula; just fill it with counting numbers.

The cell in column B, Shell, is =FLOOR((SQRT(A2)+1)/2,1)

The cell in column C, Leg, is =FLOOR((A2-(2*B2-1)^2)/2/B2,1)

The cell in column D, Element, is =(A2-(2*B2-1)^2)-2*B2*C2-B2+1

The cell in column E, x, is =IF(C2=0,B2,IF(C2=1,-D2,IF(C2=2,-B2,D2)))

The cell in column F, y, is =IF(C2=0,D2,IF(C2=1,B2,IF(C2=2,-D2,-B2)))

You can cut and paste these formulas from this message right into Excel, plot the x and y columns using a scatter plot, and within a minute or two, you'll be lookin' at the square spiral! Have fun.

Inverse Spiral Function

Then, much later, someone named Ofek emailed me to ask about the inverse.  That is, how can you get from an (x,y) pair to the distance from the origin, measured along the spiral?

Here's the answer:

Given (x,y),

shell is the maximum of the distance in either dimension from the origin, in other words: max(abs(x),abs(y))

leg -- if you think of the plane of ordered numbers as being inside a big "X", then the leg is the quadrant in that x.  In other words,

if (x,y) is closest to the positive x axis, then leg is 0
if (x,y) is closest to the positive y axis, then leg is 1
if (x,y) is closest to the negative x axis, then leg is 2
if (x,y) is closest to the negative y axis, then leg is 3

and a "tie" goes to the lower leg number (a tie between legs 3 and 0 goes to leg 3)

element is the directed distance from the axis, measured along the spiral.

Here are the calculations, which you can enter into your spreadsheet, assuming "x" is in column E, and "y" is in column F:

The cell in column G, Shell, is =MAX(ABS(E2),ABS(F2))

The cell in column H, Leg, is =IF(AND(F2<=E2,F2>-E2),0,IF(AND(F2>=-E2,F2>E2),1,IF(AND(F2>=E2,F2<-E2),2,3)))

The cell in column I, Element, is =IF(H2=0,F2,IF(H2=1,-E2,IF(H2=2,-F2,E2)))

The cell in column J, n, is =4*G2^2+(2*H2-3)*G2+I2

Now, no matter what integer values of (x,y) you type into the cells in columns E and F, you'll get the correct distance from the origin, measured along the spiral, in column J.